home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 090 / jbl.arc / LISTBOX.BAS < prev    next >
Encoding:
BASIC Source File  |  1985-08-20  |  3.8 KB  |  76 lines
  1. 1 INPUT"ENTER DRIVER DESCRIPTION                                                         ",DESC$
  2. 2 INPUT"ENTER THE DRIVER'S FREE-AIR RESONANCE FREQUENCY (fs), IN HERTZ ",F
  3. 3 IF F<.1 THEN 2
  4. 4 INPUT"ENTER THE DRIVER'S COMPLIANCE EQUIVALENT VOLUME (Vas) IN CUBIC FEET ",V
  5. 5 IF V<.1 THEN 4
  6. 6 INPUT"ENTER THE DRIVER'S TOTAL Q (Qts) ",Q
  7. 7 IF Q<.01 THEN 6
  8. 8 INPUT"ENTER THE DRIVER'S HALF-SPACE REFERENCE EFFICIENCY (n), IN PERCENT ",N
  9. 9 IF N<.1 THEN 8
  10. 10 INPUT"ENTER DRIVER'S MAXIMUM INPUT POWER CAPACITY, IN WATTS ",P
  11. 11 IF P<1 THEN 10
  12. 12 INPUT"ENTER DRIVER'S MAXIMUM PEAK LINEAR EXCURSION, IN INCHES (.5 p-p) ",X
  13. 13 IF X<.01 THEN 12
  14. 14 INPUT"ENTER DRIVER'S EFFECTIVE CONE DIAMETER IN INCHES ",D1
  15. 15 IF D1<1 THEN 14
  16. 16 L1=LOG(10) : V9=V/35.31 : Q4=7 : T7=.01*N*P : X9=X/39.37 : D9=D1/39.37
  17. 17 S=3.14159*D9^2/4 : Z1=.4375*F^4*(X9*S)^2
  18. 18 INPUT"ENTER DESIRED BOX VOLUME, (Vb) IN CUBIC FEET ",V1
  19. 19 IF V1<.1 THEN 18
  20. 20 INPUT"ENTER DESIRED HELMHOLTZ FREQUENCY, IN HERTZ AND PRESS RETURN TO BEGIN PRINT ",F1
  21. 21 IF F1<.01 THEN 20
  22. 22 IF F1=0 THEN F1=9.99E-21
  23. 23 H=F1/F : A9=V/V1
  24. 24 LPRINT DESC$
  25. 25 LPRINT"************************ DRIVER PARAMETERS ***********************"
  26. 26 LPRINT USING"FREE-AIR RESONANCE FREQUENCY (fs ) =   ###.#   Hz";F
  27. 27 LPRINT USING"COMPLIANCE EQUIVALENT VOLUME (Vas) =   ###.### ft^3";V
  28. 28 LPRINT USING" TOTAL DRIVER Q              (Qts) =    ##.### Qts";Q
  29. 29 LPRINT USING"HALF-SPACE EFFICIENCY        ( n ) =    ##.##  %";N
  30. 30 LPRINT USING"EFFECTIVE CONE DIAMETER      (Sd ) =   ###.#   in";D1
  31. 31 LPRINT USING"PEAK LINEAR EXCURSION       (Xmax) =   ###.### in";X
  32. 32 V4=3.14159*D1^2/4*X
  33. 33 LPRINT USING"PEAK DISPLACEMENT VOLUME     (Vd ) = #####.##  in^3";V4
  34. 34 LPRINT USING"THERMAL LIMIT INPUT POWER  (Ptmax) = #####.#   watts";P
  35. 35 LPRINT
  36. 36 LPRINT"************************** BOX PARAMETERS ************************"
  37. 37 LPRINT USING"NET INTERNAL VOLUME          (Vb ) =  ####.### ft^3";V1
  38. 38 LPRINT USING"HELMHOLTZ BOX RESONANCE FREQ (f1 ) =  ####.#   Hz";F1
  39. 39 LPRINT USING"BOX LEAKAGE Q                (Ql ) =  ####.#   Q";Q4
  40. 40 S4=8.25*V4/SQR(F1) : A4=1728*V1*(6.2832*F1/13504)^2 : LPRINT
  41. 41 LPRINT USING"MINIMUM VENT AREA FOR <2% Vsound IN PORT  = #######.# in^2";S4
  42. 42 LPRINT
  43. 43 LPRINT "   VENT LENGTH              VENT AREA             VENT DIAMETER "
  44. 44 LPRINT "     INCHES               SQUARE INCHES               INCHES"
  45. 45 FOR J=1 TO 5 : L4=S4/A4-.825*SQR(S4) : K=(SQR(S4/3.14159))*2
  46. 46 IF L4>.75 THEN 48
  47. 47 GOTO 52
  48. 48 LPRINT USING"   #####.##             ########.##                   ###.#";L4;S4;K
  49. 49 S4=1.25893*S4 : NEXT J : LPRINT
  50. 50 LPRINT"************************* SYSTEM PARAMETERS **********************"
  51. 51 GOTO 54
  52. 52 L4=.75 : S4=((A4*.825+SQR((A4*.825)^2+4*A4*L4))/2)^2
  53. 53 GOTO 48
  54. 54 LPRINT USING"     TUNING RATIO = H = fb/fs   =   ##.###";H
  55. 55 LPRINT USING"       ALPHA      = Vas/Vb       =   ###.###";A9 : LPRINT:LPRINT
  56. 56 LPRINT"       RELATIVE   MAXIMUM    MAXIMUM    RELATIVE   MAXIMUM    LIMIT"
  57. 57 LPRINT"FREQ   RESPONSE   ACOUSTIC    ROOM      MAXIMUM     INPUT     D=DISP"
  58. 58 LPRINT" Hz     (dB)      OUTPUT     dB SPL     OUTPUT      WATTS     T=THERM"
  59. 59 LPRINT"----   --------   --------   --------   --------   --------   --------"
  60. 60 A=H*H : B=A/Q+H/Q4 : C=1+A+A9+H/(Q4*Q) : D=1/Q+H/Q4
  61. 61 READ F9
  62. 62 IF F9>500 THEN 72
  63. 63 W=F9/F : W1=W*W : H9=W1*W1/SQR((W1*W1-C*W1+A)^2+W1*(B-D*W1)^2)
  64. 64 G=W1^4/((H*H-W1)^2+(W*H/Q4)^2) : T5=H9^2*T7 : D5=Z1*G
  65. 65 IF D5<T5 THEN 68
  66. 66 P5=T5 : P1=P : A$="T"
  67. 67 GOTO 69
  68. 68 P5=D5 : P1=D5/T5*P : A$="D"
  69. 69 V5=110+10*LOG(P5/.4)/L1 : Y=20*LOG(H9)/L1 : Y1=10*LOG(P5/T7)/L1
  70. 70 LPRINT USING"###.#   ####.#    ###.##      ###.#     ####.#    #####.#      !";F9;Y;P5;V5;Y1;P1;A$
  71. 71 GOTO 61
  72. 72 RESTORE
  73. 73 DATA 20,25,30,35,40,45,50,55,60,65,70,75,80,85,90,95,100
  74. 74 DATA 150,200,250,300,350,400,450,500,501
  75. 75 GOTO 18 : END
  76.